第 18 章 在 Business Central 中创建 DRL 规则

流程

1. 在 Business Central 中，前往 Menu → Design → Projects 并点项目名称。
2. 点 Add Asset → DRL 文件。

3. 输入信息式 DRL 文件名 并选择相应的 软件包。您指定的软件包必须是分配或将被分配所需数据对象的同一软件包。

   如果项目中已定义了任何域特定语言( DSL)资产，您也可以选择 Show 声明 DSL 句子。这些 DSL 资产将作为在 DRL 设计器中定义的条件和操作可以使用的对象。

4. 点 Ok 创建规则资产。

   新的 DRL 文件现已列在 Project Explorer 的 DRL 面板中，如果您选择了 Show 声明 DSL 句子选项，则在 DSL R 面板中列出。分配此 DRL 文件的软件包列在文件的顶部。

5. 在 DRL 设计器左侧面板中的 fact 类型 列表中，确认您的规则需要的所有数据对象和数据对象字段（每个）。如果没有，您可以使用 DRL 文件中的 import 语句从其他软件包中导入相关数据对象，或者在您的软件包中创建 数据对象。

6. 在所有数据对象都就位后，返回到 DRL 设计器的 Model 选项卡，并使用以下任何组件定义 DRL 文件：

   DRL 文件中的组件

   package
   
   import
   
   function  // Optional
   
   query  // Optional
   
   declare   // Optional
   
   global   // Optional
   
   rule "rule name"
       // Attributes
       when
           // Conditions
       then
           // Actions
   end
   
   rule "rule2 name"
   
   ...

   • 软件包:(automatic)会在创建 DRL 文件并选择软件包时为您定义。

   • 导入 ：使用它来识别来自此软件包或要在 DRL 文件中要使用的其他软件包的数据对象。以 packageName.objectName 格式指定软件包和数据对象，并在单独的行中指定多个导入。

     导入数据对象

     import org.mortgages.LoanApplication;

   • 功能 ：（可选）使用它在 DRL 文件中包含规则使用的功能。DRL 文件中的功能将语义代码放在规则源文件中，而不是在 Java 类中。如果规则中的某个部分被重复使用，并且每个规则的参数不同，则功能特别有用。在 DRL 文件中的规则上方，您可以声明函数或导入帮助程序类的静态方法作为功能，然后在规则的操作( then )部分中按名称使用函数(then)。

     使用规则（选项 1）声明并使用函数.

     function String hello(String applicantName) {
         return "Hello " + applicantName + "!";
     }
     
     rule "Using a function"
       when
         // Empty
       then
         System.out.println( hello( "James" ) );
     end

     通过规则导入并使用函数（选项 2）

     import function my.package.applicant.hello;
     
     rule "Using a function"
       when
         // Empty
       then
         System.out.println( hello( "James" ) );
     end

   • query:（可选）使用此命令搜索与 DRL 文件中规则相关的事实。您可以在 DRL 文件中添加查询定义，然后获取应用程序代码的匹配结果。查询搜索一组定义的条件，且不需要在或 随后 指定规格时使用。查询名称对于 KIE 基础是全局的，因此，在项目中的所有规则查询中必须是唯一的。要返回查询的结果，请使用 ksession.get QueryResults ("name") 构造传统的 QueryResults 定义，其中 "name" 是查询名称。这会返回一个查询结果列表，允许您检索与查询匹配的对象。在 DRL 文件中定义规则之上的查询和查询结果参数。

     DRL 文件中的查询定义示例

     query "people under the age of 21"
         $person : Person( age < 21 )
     end

     获取查询结果的应用程序代码示例

     QueryResults results = ksession.getQueryResults( "people under the age of 21" );
     System.out.println( "we have " + results.size() + " people under the age  of 21" );

   • 声明:（可选）使用它声明由 DRL 文件中的规则使用的新事实类型。Red Hat Process Automation Manager 的 java.lang 包中的默认事实类型是 对象，但您可以根据需要声明 DRL 文件中的其他类型。在 DRL 文件中声明事实类型可让您直接在决策引擎中定义新的事实模型，而无需在 Java 等低级别语言中创建模型。

     声明并使用新的事实类型

     declare Person
       name : String
       dateOfBirth : java.util.Date
       address : Address
     end
     
     rule "Using a declared type"
       when
         $p : Person( name == "James" )
       then   // Insert Mark, who is a customer of James.
         Person mark = new Person();
         mark.setName( "Mark" );
         insert( mark );
     end

   • global: （可选）使用它在 DRL 文件中包括规则要使用的全局变量。全局变量通常提供规则的数据或服务，如规则结果中使用的应用程序服务，并从规则返回数据，如规则中添加的日志或值。通过 KIE 会话配置或 REST 操作在决策引擎的工作内存中设置全局值，声明 DRL 文件中的规则以外的全局变量，然后在规则的操作（然后）部分使用。对于多个全局变量，请在 DRL 文件中使用单独的行。

     为决策引擎设置全局列表配置

     List<String> list = new ArrayList<>();
     KieSession kieSession = kiebase.newKieSession();
     kieSession.setGlobal( "myGlobalList", list );

     在规则中定义全局列表

     global java.util.List myGlobalList;
     
     rule "Using a global"
       when
         // Empty
       then
         myGlobalList.add( "My global list" );
     end

     警告

     不要使用全局变量在规则中建立条件，除非全局变量具有恒定的不可变值。全局变量不会插入到决策引擎的工作内存中，因此决策引擎无法跟踪变量的值更改。

     不要使用全局变量在规则间共享数据。规则始终原因并响应正常工作的内存状态。因此，如果要将数据从规则传递给规则，请向决策引擎的工作内存中断言数据。

   • 规则 ：使用这个方法在 DRL 文件中定义每个规则。规则包含格式规则 "name" 的规则，后跟定义规则行为的可选属性（如 salience 或 no-loop），后面是 when 和 then 定义。每个规则必须在规则软件包中具有唯一的名称。规则的 when 部分包含必须符合执行操作的条件。例如，如果银行需要 loan applicants 已有 21 余年，则 "Underage" 规则的 when 条件将是适用的 (age < 21)。规则的 then 部分包含满足规则条件部分时要执行的操作。例如，当 loan applicant 旧有 21 年时，然后 操作将被 设置( false )，因为申请者处于年龄之内。

     loan Application age 限值的规则

     rule "Underage"
       salience 15
       when
         $application : LoanApplication()
         Applicant( age < 21 )
       then
         $application.setApproved( false );
         $application.setExplanation( "Underage" );
     end

     每个 DRL 文件必须至少指定 软件包、导入、导入 和规则 组件。所有其他组件都是可选的。

     以下是 loan 应用程序决策服务中的 DRL 文件示例：

     loan application 的 DRL 文件示例

     package org.mortgages;
     
     import org.mortgages.LoanApplication;
     import org.mortgages.Bankruptcy;
     import org.mortgages.Applicant;
     
     rule "Bankruptcy history"
     	salience 10
     	when
     		$a : LoanApplication()
     		exists (Bankruptcy( yearOfOccurrence > 1990 || amountOwed > 10000 ))
     	then
     		$a.setApproved( false );
     		$a.setExplanation( "has been bankrupt" );
     		delete( $a );
     end
     
     rule "Underage"
     	salience 15
     	when
     		$application : LoanApplication()
     		Applicant( age < 21 )
     	then
     		$application.setApproved( false );
     		$application.setExplanation( "Underage" );
     		delete( $application );
     end

     图 18.1. Business Central 中 loan application 的 DRL 文件示例

     
7. 在定义了规则的所有组件后，在 DRL 设计器右上角点击 Validate 来验证 DRL 文件。如果文件验证失败，解决错误消息中描述的任何问题，查看 DRL 文件中的所有语法和组件，并尝试验证文件，直到文件通过为止。
8. 点 DRL 设计器中的 Save 保存您的更改。